(
s.options.memSize_(2.pow(20));
s.waitForBoot({
    ~makeBuffers = { |path, event, mono = false|
        var dir = PathName.new(path);
        var contents = dir.entries;
        if (contents.select({ |n| n.isFile }).size > 0)
        {
            var files, bufArray;
            files = contents.select({ |n| n.isFile });
            files = files.select({ |n|
                ["aif", "aiff", "wav"].includesEqual(n.extension)
            });
            if (event[dir.folderName.asSymbol] != nil)
            { "duplicate subfolder name ignored".warn; }
            {
                bufArray = files.collect({ |n|
                    if(mono)
                    { Buffer.readChannel(s, n.fullPath, channels:[0]) }
                    { Buffer.read(s, n.fullPath) };
                });
                event[dir.folderName.asSymbol] = bufArray;
            };
        };
        if (contents.select({ |n| n.isFolder }).size > 0)
        {
            var folders = contents.select({ |n| n.isFolder });
            folders.do({ |n| ~makeBuffers.(n.fullPath, event, mono) });
        };
        event;
    };
	"instruments.scd".loadRelative;
});
)